Metastock: Ichimoku Kinko Hyo Handelssystem
Hallo Metatrader.
Ich bin gerade dabei mich näher mit dem IKH-System auseinanderzusetzen.
Nun stelle ich mir die Frage, ob es in Deiner Datenbank Material zum IKH gibt?
Und falls die Frage mit Ja zu beantworten ist, ob Du auch bereit wärst dies hier zu kommunzieren.
Danke.
Kater
Geschrieben von kater
am
@ Kater
Beim Ichikumo muss ich passen, allerdings könnte ich dir mit Ichimoku Kinko Hyo weiterhelfen. ;)
Die Formel für die einzelnen Komponenten lautet:
TenkSen:=(HHV(H,26)+LLV(L,26))/2;
KinjSen:=(HHV(H,9)+LLV(L,9))/2;
SenkuA:=Ref((TenkSen+KinjSen)/2,-25);
SenkuB:=Ref((HHV(H,52)+LLV(L,52))/2,-25);
CLOSE;TenkSen;KinjSen;SenkuA;SenkuB
In der Original MetaStock Formel wird der Close um 26 Bars nach hinten verschoben (Graphik oben, schwarze Linie), hierzu ist mir irgendwie nichts eingefallen. Die schönen "Wolken" kann man in der Custom Formel leider auch nicht abbilden. Ansonsten sollten die Werte stimmen.
@ metatrader
Vielen Dank für die Berichtigung des ICHIKUMO ;-) und die genannten Formeln. Dann kann man über Deine Datenbank sagen, dass sie zu diesem Thema auch nichts genaueres weiss.
Ich würde mich freuen, wenn ich mich nach Entwurf eines kleinen HS nochmals an Dich wenden dürfte.
Einstweilen mal vielen Dank.
Kater
Kater,
dann musst deine Frage lauten: Hast du ein Ichimoku Handelssystem in deiner Datenbank?
Und dann hätte ich gesagt: Na klar hab ich das. ;)
@ Metatrader
Alle Achtung! Wer die richtigen Fragen weiss, scheint ziemlich weit zu kommen.
Dürfte ich Dich um Bekanntgabe des ICHIKUMO-Sytems Deiner Datenbank bitten? Bin mal gespannt, ob da der gleiche Ansatz verfolgt wurde, wie ich es vorhabe.
Kater
Kater,
genau wie im richtigen Leben: Wer die richtige Frage stellt, erhält eine gute Antwort. ;)
Das System ist die Umsetzung eines TASC Artikels:
{EL}
TenkSen:=(HHV(H,26)+LLV(L,26))/2;
KinjSen:=(HHV(H,9)+LLV(L,9))/2;
SenkuA:=Ref((TenkSen+KinjSen)/2,-25);
SenkuB:=Ref((HHV(H,52)+LLV(L,52))/2,-25);
EL:= If(SenkuA>=SenkuB,Cross(C,SenkuA),Cross(C,SenkuB));
CL:= If(SenkuA>=SenkuB,Cross(SenkuA,C),Cross(SenkuB,C));
ES:= If(SenkuA>=SenkuB,Cross(SenkuB,C),Cross(SenkuA,C));
CS:= If(SenkuA>=SenkuB,Cross(C,SenkuB),Cross(C,SenkuA));
I:=Cum(EL>-1 AND CL>-1 AND ES>-1 AND CS>-1)=1;
State:= (BarsSince(El OR I)<BarsSince(Cl OR I)) -
(BarsSince(Es OR I)<BarsSince(Cs OR I));
State=1 AND Ref(State,-1)<1
{ES}
TenkSen:=(HHV(H,26)+LLV(L,26))/2;
KinjSen:=(HHV(H,9)+LLV(L,9))/2;
SenkuA:=Ref((TenkSen+KinjSen)/2,-25);
SenkuB:=Ref((HHV(H,52)+LLV(L,52))/2,-25);
EL:= If(SenkuA>=SenkuB,Cross(C,SenkuA),Cross(C,SenkuB));
CL:= If(SenkuA>=SenkuB,Cross(SenkuA,C),Cross(SenkuB,C));
ES:= If(SenkuA>=SenkuB,Cross(SenkuB,C),Cross(SenkuA,C));
CS:= If(SenkuA>=SenkuB,Cross(C,SenkuB),Cross(C,SenkuA));
I:=Cum(EL>-1 AND CL>-1 AND ES>-1 AND CS>-1)=1;
State:=(BarsSince(Es OR I)<BarsSince(Cs OR I))-(BarsSince(El OR I)<BarsSince(Cl OR I));
State=1 AND Ref(State,-1)<1
{CL}
TenkSen:=(HHV(H,26)+LLV(L,26))/2;
KinjSen:=(HHV(H,9)+LLV(L,9))/2;
SenkuA:=Ref((TenkSen+KinjSen)/2,-25);
SenkuB:=Ref((HHV(H,52)+LLV(L,52))/2,-25);
EL:= If(SenkuA>=SenkuB,Cross(C,SenkuA),Cross(C,SenkuB));
CL:= If(SenkuA>=SenkuB,Cross(SenkuA,C),Cross(SenkuB,C));
ES:= If(SenkuA>=SenkuB,Cross(SenkuB,C),Cross(SenkuA,C));
CS:= If(SenkuA>=SenkuB,Cross(C,SenkuB),Cross(C,SenkuA));
I:=Cum(EL>-1 AND CL>-1 AND ES>-1 AND CS>-1)=1;
State:=(BarsSince(Cl OR I)<BarsSince(El OR I)) -
(BarsSince(Es OR I)<BarsSince(Cs OR I));
State=1 AND Ref(State,-1)<1
{CS}
TenkSen:=(HHV(H,26)+LLV(L,26))/2;
KinjSen:=(HHV(H,9)+LLV(L,9))/2;
SenkuA:=Ref((TenkSen+KinjSen)/2,-25);
SenkuB:=Ref((HHV(H,52)+LLV(L,52))/2,-25);
EL:= If(SenkuA>=SenkuB,Cross(C,SenkuA),Cross(C,SenkuB));
CL:= If(SenkuA>=SenkuB,Cross(SenkuA,C),Cross(SenkuB,C));
ES:= If(SenkuA>=SenkuB,Cross(SenkuB,C),Cross(SenkuA,C));
CS:= If(SenkuA>=SenkuB,Cross(C,SenkuB),Cross(C,SenkuA));
I:=Cum(EL>-1 AND CL>-1 AND ES>-1 AND CS>-1)=1;
State:=(BarsSince(Cs OR I)<BarsSince(Es OR I))-(BarsSince(El OR I)<BarsSince(Cl OR I));
State=1 AND Ref(State,-1)<1
Wow, das System ist aber ein echter "Burner". ;-)) Zumindest auf den DAX angewandt.
Da ist ja EW noch besser. ;-)
greetz
aureleus
@ Metatrader
Vielen Dank für das System.
Wie aurelius habe auch ich nach einem Test auf das Dax30-Portfolio gemerkt, dass sich dieses System nicht sehr positiv auf den eigenen Geldbeutel auswirken würde.
Werde mich diese Woche mit den Signalen des Systems auseinandersetzen und hier meine Handelspunkte posten. Vielleicht kann der ein oder andere Meta(stock)trader die Handelspunkte in ein System fassen.
;-)
Kater