Metastock: Stopps im Expert Advisor

@ dhoell1 [#1]

Hier ein komplettes Expert Advisor Beispiel mit Stops.

Neuen Indikator anlegen
Name: MACD System Indikator mit Case Stop Typ3

ShortMA:= Input("Short EMA",1,200,12); {OPT1}
LongMA:= Input("Long EMA",1,200,26); {OPT2}
MovAvg:=Input("Mov",1,200,9); {OPT3}
periods:=30; {OPT4}
hlperiod:=20; {OPT5}
cMACD:=Mov(C,ShortMA,E) - Mov(C,LongMA,E);
cTrigger:=Mov(Mov(C,ShortMA,E) - Mov(C,LongMA,E),MovAvg,E);

RWH:=(H-Ref(L,-periods))/(ATR(periods)*Sqrt(periods));
RWL:=(Ref(H,-periods)-L)/(ATR(periods)*Sqrt(periods));
Pk:=Mov((RWH-RWL),3,W);
AVTR:=Mov(HHV(H,2) - LLV(L,2), hlperiod, S);
SD:=Stdev(HHV(H,2) - LLV(L,2), hlperiod);
Val3:=If(Pk>0,HHV(H-AVTR-2*SD, hlperiod),LLV(L+AVTR+2*SD, hlperiod));
EL:= (cTrigger <cMACD) AND (Val3<C);
CL:= (Val3>C) OR ((cTrigger>cMACD) AND Val3>C);
ES:= (cTrigger>cMACD) AND (Val3>C);
CS:= (Val3<C) OR ((cTrigger <cMACD) AND Val3<C);

State:=If(Cum(1)=1,0,If(EL,1,If(ES,-1,If((CL AND PREV=1) OR (CS AND PREV=-1),0,PREV))));
{Falls die Datei TMW.DLL vorhanden ist}
{state:=ExtFml( "tmw.Latch", EL, CL, ES, CS);}

State

-----------------------------
Ende Indikator
-----------------------------

Neuen Expert Advisor anlegen

Highlights

Long
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=1 {grüne Farbe}

Short
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=-1 {rote Farbe}

Symbols:

Enter Long
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=1 AND Ref(State,-1)<1 {EL}

Enter Short
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=-1 AND Ref(State,-1)>-1 {ES}

Close Long
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=0 AND Ref(State,-1)=1 {CL}

Close Short

state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=0 AND Ref(State,-1)=-1 {CS}

Trends:

Bullish
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=1 {grüne Farbe}

Bearish
state:=Fml("MACD System Indikator mit Case Stop Typ3");
State=-1 {rote Farbe}

Vielen Dank für diese göttliche Erläuterung ! ;)