* Dax Future Analysen (Sammelbeitrag)
Dieser Beitrag soll zukünftig als eine Art Sammelbeitrag für kurzfristige Dax Future Analysen dienen, analysiert wird jeweils der aktuelle Kontrakt, eine Rollover erfolgt nach dann jeweils nach dem Verfallstag.
Die auf dieser Seite von mir veröffentlichten Analysen stellen keine Anlageberatung dar, sondern geben lediglich meine persönliche Einschätzung wieder. Für die Richtigkeit der auf dieser Seite enthaltenen Angaben oder Einschätzungen kann keine Gewähr übernommen werden.
DAX-Future 03/09 (846959) Intervall: 30 Minuten
Aktuell befindet sich der FDAX in einer Korrekturphase, wobei die folgenden Bewegungen für die weitere Entwicklung relevant erscheinen:
Hellgrün: Low bei 3538 bis High 3668.5
Dunkelgrün: Low bei 3442 bis High 3668.5
Der zentrale Bereich ist momentan der Bereich um 3590 Punkten, hier befinden sich das 38.2% Retracement dunkelgrün, das 61.8% Retracement hellgrün, das Zwischenhoch vom 22.8.2003 (3595 Punkte) und ein noch offenes Gap (3570 - 3605).
Sollte der Kurs unterhalb von 3590 Punkten fallen, "droht" ein Gap Close (mind. bis 3570), damit hätte die hellgrüne Aufwärtsbewegung vorerst zu stark korrigiert, um weiter fortgesetzt werden zu können, es "droht" ein Retest des Bereiches 3540 (zugleich 61.8% Retracement dunkelgrün).
Der Volume at Price Indikator soll uns helfen, die (Kurs)Bereiche im Chart zu finden, an denen man durch erhöhtes Volumen (Peaks im Indikator) stärkere Unterstützung oder Widerstand vermuten kann. Folgende Bereiche erhalten eine entscheidende Bedeutung:
Widerstände:
Rot 1: 3623
Rot 2: 3637, 3645
Unterstützungen:
Grün 1: 3565, 3556 (stark)
Grün 2: 3528 (stark), 3515
Grün 3: 3488, 3472,3465
==> Praktische Konsequenzen
Die aktuelle Positionierung ist short, als Stopp für bestehende Short Positionen könnte man sich an den folgenden Chartmarken orientieren: 3623, 3637, 3645, 3677 (je nach Risikoneigung), das angepeilte Kursziel liegt im Bereich 3560 Punkten.
Falls man flat ist, gilt es das Verhalten des FDAX im Bereich von 3590/3600 zu beobachten, Kurse unterhalb von 3590 könnten zu den oben angesprochenen Korrekturen bis in Bereich 3540 führen ==> Entry short unterhalb von 3590.
Falls man long ist, sollten Trading Long Positionen im Bereich 3590 durch einen Stopp abgesichert werden ==> Exit Long unterhalb von 3590.
Da anscheinend im Moment die wichtigen Marktteilnehmer keine fallenden Kurse sehen wollen und wir in Folge dessen einen "brutalen" Bullenmarkt haben, kommt man einfach nicht umhin, sich mit dem Aufbau von neuen (Trading) Long Positionen zu beschäftigen, zudem liegt auch aus Sicht der beiden hier betrachteten Bewegungen immer noch ein intakter Aufwärtstrend vor.
Daher könnte man (je nach Risikoneigung/Stimmung am Montag) in den folgenden Bereich neue (Trading) Long Positionen aufbauen:
Oberhalb der Widerstandsmarken 3623, 3637, 3645, 3677
Am Support 3590, 3556/3565, 3528, 3515, 3488
EMail Frage:
Ich bin beeindruckt von der grafischen, mehrfarbigen Aufbereitung des f-dax-handels!
Zum Text hätte ich eine Frage:
Wer flat ist, solle einen short entry unterhalb 3590 ins Auge fassen, schreiben sie. Ihr Artikel endet mit der Bemerkung, am Widerstand 3590 solle ein Aufbau von Long-positionen erwogen werden.
Ist das nicht eine ausschließlich Spesen produzierende Strategie ? Je mehr Spesen, je öfter um diese Handelsmarke gerungen wird?
--------------
Antwort:
Der übergeordnete Trend ist extrem bullish, bislang sind die Kursverluste von Freitag in meinen Augen noch nicht als ein Trendwechsel, sondern als eine ganz normale technische Korrektur zu sehen, die idealerweise im Bereich 3600/3590 Punken enden könnte oder sollte. Hierdurch begründet sich dann die Bemerkung, im Bereich 3590 sollte ein Aufbau erwägt werden. Unterstellt man z.B. eine neutrale Eröffnung im Bereich 3606, so kann auch direkt mit einem Stopp bei 3590 long gehen.
Wenn ich dann in diesem Bereich long einsteigen kann, sichere ich diese Position mit einem Stopp ab, sollte der FDAX dann zwischen z.B. 3605 und 3590 oszillieren, so bin ich ja nicht gezwungen, meine Position zu switchen. Auf der Oberseite liegt der nächste stärkere Widerstand erst im Bereich 3640 Punkte, so dass auch der direkte Einstieg (also 3606) noch ein vertretbares Chance/Risiko Verhältnis.
Die aktuelle Short Positionierung begründet sich durch das abgebildete System.
DAX-Future 03/09 (846959) Intervall: 10 Minuten
Auf den besonderen Wunsch eines einzelnen Herrn wird heute der FDAX mit dem New Dimension System von Bill Williams ( http://www.profitunity.com ) dargestellt. Das System ist in ähnlicher Form in MetaStock zwar als Expert verfügbar, leider ist der Code aber Passwort geschützt und somit als eine Black Box mehr oder weniger nicht einsetzbar.
Das System ist
Long, falls:
Schlusskurs oberhalb des Alligators; AO steigend, AC steigend
oder Schlusskurs innerhalb des Alligators; AO steigend, AC steigend
oder Schlusskurs unterhalb des Alligators; AO steigend, AC steigend
Nix konkretes, auf der Lauer liegen:
Schlusskurs oberhalb des Alligators; AO fallend, AC steigend
oder Schlusskurs innerhalb des Alligators; AO fallend, AC steigend
oder Schlusskurs unterhalb des Alligators; AO fallend, AC steigend
oder Schlusskurs oberhalb des Alligators; AO steigend, AC fallend
oder Schlusskurs innerhalb des Alligators; AO steigend, AC fallend
oder Schlusskurs unterhalb des Alligators; AO steigend, AC fallend
Short, falls:
Schlusskurs oberhalb des Alligators; AO fallend, AC fallend
oder Schlusskurs innerhalb des Alligators; AO fallend, AC fallend
oder Schlusskurs unterhalb des Alligators; AO fallend, AC fallend
Ergänzend zu dem System sind noch einige Ideen von Bill Williams (Fraktal Buy, First Bullet, Twin Peak, ...) in dem Expert als Symbole hinterlegt. Sollten noch irgendwelche Unklarheiten bzgl. des Systems bestehen, so bitte nachfragen.
Zum FDAX:
Es hat sich nicht viel getan, leider wurde das "optimale" Einstiegsniveau im Bereich 3605/3590 nicht erreicht, es blieb also nur der etwas ärgerlichere Einstieg oberhalb von 3623. Das abgebildete System ist momentan long, die Bullen waren zwar etwas schlapp auf der Brust, der FDAX konnte aber immerhin die Widerstände im Bereich 3630, 3640 und 3650 überwinden.
Da die Zeiteinstellung diesmal sehr kurzfristig (10 Minuten ist), können alle relevanten Chartmarken bequem abgelesen werden.
----------------------
MetaStock Formeln:
----------------------
Alligator Blue
Ref(Wilders(MP(),13),-8)
----------------------
Alligator Green
Ref(Wilders(MP(),5),-3)
----------------------
Alligator Red
Ref(Wilders(MP(),8),-5)
----------------------
AO+
var1 := Mov((L+H)/2 ,34 ,S ) ;
var2 := Mov((L+H)/2 , 5 ,S ) ;
Var2-var1
----------------------
AO Red
If(Fml( "AO+") <= Ref( Fml( "AO+"), -1 ), Fml( "AO+"),0)
----------------------
AO Green
If(Fml( "AO+") >Ref( Fml( "AO+"), -1 ), Fml( "AO+"),0)
----------------------
AC Green
If(Fml( "AC+") > Ref( Fml( "AC+"), -1 ), Fml( "AC+"),0);
----------------------
AC Red
If(Fml( "AC+") <= Ref( Fml( "AC+"), -1 ), Fml( "AC+"),0);
----------------------
AC+
Fml("AO+") - Mov(Fml("AO+"), 5, E)
----------------------
Fractal Up
ValueWhen(1,H<Ref(H,-2) AND Ref(H,-1)<Ref(H,-2) AND Ref(H,-3)<Ref(H,-2) AND Ref(H,-4)<Ref(H,-2),Ref(H,-2))
----------------------
Fractal Down
ValueWhen(1,L>Ref(L,-2) AND Ref(L,-1)>Ref(L,-2) AND Ref(L,-3)>Ref(L,-2) AND Ref(L,-4)>Ref(L,-2),Ref(L,-2))
----------------------
Expert:
Trends:
selbst programmieren, Regeln oben
----------------------
Commentary
Alligator Jaw (Blue) : writeval(fml("Alligator Blue"),6.3)
Alligator Teeth (Red ) : writeval(fml("Alligator Red"),6.3)
Alligator Lips (Green) : writeval(fml("Alligator Green"),6.3)
Fractal Up (Buy): writeval(fml("Fractal Up"),6.3)
Fractal Down (Sell): writeval(fml("Fractal Down"),6.3)
usw....
----------------------
Highlights
Green Zone, green
(Fml("AO+") > Ref(Fml("AO+"), -1)) AND (Fml("AC+") > Ref(Fml("AC+"), -1))
----------------------
Red Zone, red
(Fml("AO+") < Ref(Fml("AO+"), -1)) AND (Fml("AC+") < Ref(Fml("AC+"), -1))
----------------------
Squat, blue
If(MarketFacIndex()>Ref(MarketFacIndex(),-1) AND
V>Ref(V,-1),1,If(MarketFacIndex()<Ref(MarketFacIndex(),-1) AND
V>Ref(V,-1),2,If(MarketFacIndex()<Ref(MarketFacIndex(),-1) AND
V<Ref(V,-1),3,If(MarketFacIndex()>Ref(MarketFacIndex(),-1) AND
V<Ref(V,-1),4,0))))=2
---------
Expert Symbols
Name, Farbe
----------------------
Simple Up Fractal Buy, Pale green up
var1 := Fml("Alligator Green");
var2 := Fml("Alligator Red");
var3 := Fml("Alligator Blue");
Cross(H , Fml("Fractal Up") )
AND ((var1 > var2)
AND (var1 > var3))
----------------------
First Bullet-buy, green up
red := Fml( "Alligator Red") ;
green:= Fml( "Alligator Green") ;
Blue := Fml( "Alligator Blue");
A:=(Abs(red-blue)+Abs(red-green)+Abs(blue-green))/3;
MA:=Mov(A,20,S);
VA:=(A-MA)/MA ;
SleepAllig:= VA<0;
hh:= Ref(H,-2);
var1:=ValueWhen(1,
(hh > Ref(H, -4)) AND
(hh > Ref(H, -3)) AND
(hh > Ref(H, -1)) AND
(hh > H) AND Ref(H,-2)>red AND sleepallig, Ref(H,-2));
fractalup:=HighestSince(1,var1,var1);
buystop:=If(HIGH > red AND
HIGH > fractalup AND
fractalup > red,fractalup,0);
buy:=Cross(H,fractalup);
Entry:=fractalup<>Ref(fractalup,-1);
Exit:= buy;
Init:=Cum(Entry<>2 AND Exit<>2)=1;
Trade:=If(BarsSince(Init OR Entry) >= BarsSince(Init OR Exit),0,1);
FirstExit:=buy AND Ref(Trade,-1);
Firstexit
----------------------
First Bullet Add-on-buy, Lime green up
red := Fml( "Alligator Red") ;
green:= Fml( "Alligator Green") ;
Blue := Fml( "Alligator Blue");
A:=(Abs(red-blue)+Abs(red-green)+Abs(blue-green))/3;
MA:=Mov(A,20,S);
VA:=(A-MA)/MA ;
SleepAllig:= VA<0;
hh:= Ref(H,-2);
var1:=ValueWhen(1,
(hh > Ref(H, -4)) AND
(hh > Ref(H, -3)) AND
(hh > Ref(H, -1)) AND
(hh > H) AND Ref(H,-2)>red , Ref(H,-2));
fractalup:=HighestSince(1,var1,var1);
Cross(H,fractalup)
----------------------
Second Bullet-Saucer-buy , Bright green up
Lg:=C-Wilders(C,13);
St:=C-Wilders(C,5);
Trendup:=(st<lg) AND Lg>0;
AO:=Mov(MP(),5,S) - Mov(MP(),34,S);
AOG:=If( AO,>,Ref(AO,-1),AO,0);
AOR:=If(AO,<=,Ref(AO,-1), AO,0);
AO > Ref(AO,-1) AND Ref(AO,-1) < Ref(AO,-2) AND AO>0 AND Ref(AO,-1)>0 AND
Ref(AO,-2)>0 AND AOG AND Ref(AOR,-1) AND Trendup
----------------------
Second Bullet Twin Peak-buy, Teal up
AO :=Mov(MP(),5,S) - Mov(MP(),34,S);
AOG:=If( AO,>,Ref(AO,-1),AO,0);
AOR:=If(AO,<=,Ref(AO,-1), AO,0);
b:=ValueWhen(1,Ref(AOr,-1)AND AOG,Ref(AO,-1));
a:=ValueWhen(2,Ref(AOr,-1)AND AOG,Ref(AO,-1));
Ref(AOR,-1)AND AOG AND a<b AND a<0 AND b<0
AND BarsSince(Cross(AO,0)) > PeakBars(2,AOG AND Ref(AOR,-1),1)
----------------------
Third Bullet AC+ above zero--buy, Pale Blue up
AO:=Mov(MP(),5,S) - Mov(MP(),34,S);
AC:= AO - Mov(AO , 5, S);
ACG:= Fml( "AC green");
ACR:= Fml( "AC red");
AOG:= Fml( "AO green");
AOR:= Fml( "AO red");
AC > Ref(AC,-1) AND
Ref(AC,-1)>Ref(AC,-2) AND
Ref(AC,-2)<Ref(AC,-3) AND
Ref(AC,-1)>0 AND
Ref(AC,-2)>0 AND
Ref(AC,-3)>0 AND
AC >0 AND
Ref(ACR,-2) AND Ref(ACG,-1) AND ACG
----------------------
Third Bullet AC+ under zero-buy, Blue grey up
AO:=Mov(MP(),5,S) - Mov(MP(),34,S);
AC:= AO - Mov(AO , 5, S);
ACG:= Fml( "AC green");
ACR:= Fml( "AC red");
AOG:= Fml( "AO green");
AOR:= Fml( "AO red");
AC >Ref(AC,-1) AND
Ref(AC,-1) > Ref(AC,-2) AND
Ref(AC,-2) > Ref(AC,-3) AND
Ref(AC,-3) < Ref(AC,-4) AND
Ref(AC,-1)<0 AND
Ref(AC,-2)<0 AND
Ref(AC,-3)<0 AND
Ref(AC,-4)<0 AND
AC <0 AND
ACG AND Ref(ACG,-1) AND Ref(ACG,-2) AND Ref(ACR,-3)
----------------------
Fourth Bullet - the zone-buy, Aqua up
red := Fml( "Alligator Red") ;
green:= Fml( "Alligator Green") ;
Blue := Fml( "Alligator Blue");
AO:=Mov(MP(),5,S) - Mov(MP(),34,S);
AC:= AO - Mov(AO , 5, S);
ACG:= Fml( "AC green");
ACR:= Fml( "AC red");
AOG:= Fml( "AO green");
AOR:= Fml( "AO red");
Green:=acg AND aog;
Red:=aor AND acr;
Gray:=(acg AND acr) OR (aog AND aor);
B:=Sum(green,5);
Add1:=If(Ref(red OR gray,-3) AND Ref(green,-2) AND Ref(green,-1) AND green
AND C>Ref(C,-1),1,0);
Add2:=If(Ref(red OR gray,-4) AND Ref(green,-3) AND Ref(green,-2) AND
Ref(green,-1)AND green AND C>Ref(C,-1),1,0);
Add3:=If(Ref(red OR gray,-5) AND Ref(green,-4) AND Ref(green,-3) AND
Ref(green,-2) AND Ref(green,-1)AND green AND C>Ref(C,-1),1,0);
add1 + add2 +add3
----------------------
Sell below red line-sell, Tan down
red := Fml( "Alligator Red") ;
Cross(red , CLOSE)
----------------------
First Bullet Fractal Sale, Dark Red down
red := Fml( "alligator Red") ;
ll:= Ref(L,-2);
var1:=ValueWhen(1,
(ll < Ref(L, -4)) AND
(ll < Ref(L, -3)) AND
(ll < Ref(L, -1)) AND
(ll < L) AND Ref(L,-2)<red, Ref(L,-2));
fractaldw:=LowestSince(1,var1,var1);
sellstop:=If(LOW < red AND
LOW > fractaldw AND
fractaldw < red,fractaldw,0);
sell:=Cross(fractaldw,L);
Entry:=fractaldw<>Ref(fractaldw,-1);
Exit:= sell;
Init:=Cum(Entry<>2 AND Exit<>2)=1;
Trade:=If(BarsSince(Init OR Entry) >= BarsSince(Init OR Exit),0,1);
FirstExit:=sell AND Ref(Trade,-1);
Firstexit
----------------------
First Bullet 5 consecutive bars-sell, Brown down
ACG:= Fml( "AC green");
AOG:= Fml( "AO green");
Green:=acg AND aog;
A:=Sum(C>Ref(L,-1),1)=1;
B:=Sum(green,5)= 5;
vara:= ValueWhen(1,a,L);
varb:= ValueWhen(1,b,L);
stop:=HighestSince(1,Sum(vara,1)=Sum(varb,1) ,Ref(L,-1));
exit:=Cross(stop , C) AND (ACG AND AOG)<>1;
Entry:=b;
Exit:= exit;
Init:=Cum(Entry<>2 AND Exit<>2)=1;
Trade:=If(BarsSince(Init OR Entry) >= BarsSince(Init OR Exit),0,1);
FirstExit:=exit AND Ref(Trade,-1);
FirstExit
----------------------
Second Bullet AO saucer sale-sell, Orange down
St:=C-Wilders(C,5);
Lg:=C-Wilders(C,13);
Trendwn:=(st>lg)AND Lg<0;
AO:=Mov(MP(),5,S) - Mov(MP(),34,S);
AOG:=If( AO,>,Ref(AO,-1),AO,0);
AOR:=If(AO,<=,Ref(AO,-1), AO,0);
AO < Ref(AO,-1) AND Ref(AO,-1) > Ref(AO,-2) AND AO<0 AND Ref(AO,-1)<0 AND
Ref(AO,-2)<0 AND AOR AND Ref(AOG,-1) AND Trendwn
----------------------
Second Bullet Twin Peak Sale-sell, Light Orange down
AO :=Mov(MP(),5,S) - Mov(MP(),34,S);
AOG:=If( AO,>,Ref(AO,-1),AO,0);
AOR:=If(AO,<=,Ref(AO,-1), AO,0);
B:=ValueWhen(1,AOR AND Ref(AOG,-1),Ref(AO,-1));
A:=ValueWhen(2,AOR AND Ref(AOG,-1),Ref(AO,-1));
A>0 AND B>0 AND A>B
AND AOR AND Ref(AOG,-1)
AND BarsSince(Cross(0,AO)) >
PeakBars(2,AOR AND Ref(AOG,-1),1)
----------------------
Second Bullet AC-sell above zero, Pink down
AO:=Mov(MP(),5,S) - Mov(MP(),34,S);
AC:= AO - Mov(AO , 5, S);
ACG:= Fml( "AC green");
ACR:= Fml( "AC red");
AOG:= Fml( "AO green");
AOR:= Fml( "AO red");
AC <Ref(AC,-1) AND
Ref(AC,-1)<Ref(AC,-2) AND
Ref(AC,-2)<Ref(AC,-3) AND
Ref(AC,-3)>Ref(AC,-4) AND
Ref(AC,-1)>0 AND
Ref(AC,-2)>0 AND
Ref(AC,-3)>0 AND
Ref(AC,-4)>0 AND
AC >0 AND
ACR AND Ref(ACR,-1) AND Ref(ACR,-2) AND Ref(ACG,-3)
----------------------
Big Sell-sell, Red down
Ref(C,-1) < Fml( "Fractal Up") AND
H < Ref(H,-1) AND Ref(H,-2) > Ref(Fml("Fractal Up"),-2)
AND ( C < Fml("Alligator Green")
OR L < Fml("Fractal Down")
)
----------------------
@ metatrader
Der einzelner Herr bedankt sich recht herzlich für die umfangreiche Erklärung und den code.
Thx, metatrader.
:)
Grüße
Joram
@ metatrader,
danke noch mal für Code und Erklärung. Ich experimetiere jetzt mit dem System Intraday. Da gibt es jede Menge Signale. Und dazu die verschieden Farben :) Da wird einem schnell bunt im Kopf. Und zwar ohne LSD oder Pilze ;)
Gibt es eine Abstufung der Signale? Welche Bedeutung haben Fraktal Buy, First Bullet, Twin Peak u.ä.? Sind alle gleichrangig?
Kannst du sagen welche timeframe ist für das System geeignet? Ich versuche es mit 5 Minuten. Hast du mal vielleicht mit dem Systemtester eine Auswertung des Systems gemacht? Für weiter Erklärung wäre ich sehr dankbar.
Grüße
Joram
@ metatrader
Jetzt hole ich mal den Beitrag aus der Versenkung, weil hier die Formeln für Bill Williams System aufgeführt sind. Ich brüte gerade darüber und sehe eine Unstimmigkeit beim AC. Wenn es keine ist, bitte korrigieren.
Im Buch steht: "The AC histogram is a 5-bar simple moving average of the difference between the 5/34 momentum histogram and a 5-bar simple moving average of the difference."
Die Formel hier im Thread lautet:
"AC+
Fml("AO+") - Mov(Fml("AO+"), 5, E)"
Mov(Fml("AO+"), 5, E) ist zum Einen kein simple moving average und von der kompletten Formel müsste m.E. noch mal ein 5-bar SMA gebildet werden, damit es stimmt.
Die Formel wäre daher eher
Mov(Fml("AO+") - Mov(Fml("AO+"), 5, S),5,S);
Der Satz im Buch ist allerdings auch ein wenig komplex ausgedrückt und vielleicht habe ich ihn falsch verstanden?
Viele Grüße
Danke gautama2, da hast Du ja wieder einen Superbeitrag von Metatrader ausgegraben. Merkwürdig nur, dass da niemand richtig was gefragt hat oder gepostet danach.
@ metatrader
Du nennst es "Der Volume at Price Indikator", andere wohl Market Profile.
http://www.tripletop.de/ hat sowas ähnliches auch bei den P&F charts. Warum diskutiert hier eigentlich niemand über P&F ?
Wie berechnest Du diese bars ? Gleichgewichtet oder zeitabhängig, d.h. aktuellere Bars sind höher bewertet als ältere ?
danke & gruss hans
@ gautama2
Ich habe jetzt AC Green von ProfUn Expert (Metastock 8.0) mit crack gesehen. Das Original sagt:
If((Mov(((H+L)/2),5,S)-Mov(((H+L)/2),34,S))>(Ref(Mov(((H+L)/2),5,S),-1)-Ref(Mov(((H+L)/2),34,S),-1)),(Mov(((H+L)/2),5,S)-Mov(((H+L)/2),34,S)),0)
Grüsse
Sorry, das war AO Green!
AC Green:
(If((Mov(((H+L)/2),5,S)-Mov(((H+L)/2),34,S))-Mov((Mov(((H+L)/2),5,S)-Mov(((H+L)/2),34,S)),5,S)>(Ref(Mov(((H+L)/2),5,S),-1)-Ref(Mov(((H+L)/2),34,S),-1))-Mov((Ref(Mov(((H+L)/2),5,S),-1)-Ref(Mov(((H+L)/2),34,S),-1)),5,S),(Mov(((H+L)/2),5,S)-Mov(((H+L)/2),34,S))-Mov((Mov(((H+L)/2),5,S)-Mov(((H+L)/2),34,S)),5,S),0))
Hier eine Beschreibung und zusätzlicher code für die Alligatoren Bande von Williams.
Diesmal aber nicht für die Metastock Gemeinde. Vielleicht hilft es.
Gruss
http://home.t-online.de/home/UWKaestner/
@ Sailor
Danke, aber der schreibt es doch genauso wie metatrader. Von einer Quelle auf die nächste gleichlautende Quelle verwiesen zu werden hilft ja leider nicht weiter. Wer weiß ob Herr Kästner nicht von metatrader abgeschrieben hat oder umgekehrt, oder beide von jemand anders. :)
Wie auch immer. Ich verdeutliche nochmal:
"The AC histogram is a 5-bar simple moving average of the difference between the 5/34 momentum histogram and a 5-bar simple moving average of the difference."
Da wird über einen 5er GD gesprochen aus einer Differenz zwischen dem AO und dem 5er GD des AO. Müsste also heissen:
5erGD(AO-5erGD(AO)), wenn man die "difference" im Satz als AO deutet. So gesehen hat man keinen AC, wenn man nur die Differenz aus dem AO mit seinem 5erGD bildet.
Viele Grüße
@ gautama2
Ich lese zur Zeit gerade Bill Williams zweites Buch und lese in besagtem Abschnitt exakt dasselbe wie du. Wenn mich meine bescheidenen Englischkentnisse nicht im Stich lassen so lautet meine Übersetzung wie deine. Bloss scheint sich der Rest der Welt darauf geeinigt zu haben dass das ganze auschaut wie von Metatrader formuliert? :-(
Gruss,
Martin
Ach, endlich versteht mich einer. :)
Der Rest der Welt ist mir wurscht. Von denen hat mir noch keiner ein Bier bezahlt. Ich habe jetzt eine Anfrage an profitunity.com geschickt. Mal schauen was die antworten. Im Buch steht auf Seite 85 der middleprice mit (H-L)/2. Muss auch (H+L)/2 heißen. Manche heiße Kandidaten, die Formeln veröffentlichen haben leider das Buch dem gesunden Menschenverstand vorgezogen. Beim AC hilft mir der gesunde Menschenverstand leider nicht weiter. Wenn ich Antwort habe gebe ich Bescheid.
Viele Grüße
P.S. Simple Up Fractal Buy, Pale green up
var1 := Fml("Alligator Green");
var2 := Fml("Alligator Red");
var3 := Fml("Alligator Blue");
Cross(H , Fml("Fractal Up") )
AND ((var1 > var2)
AND (var1 > var3))
Die Bedingung für die Alligatorlinien (AND ((var1 > var2) AND (var1 > var3))) ist nicht immer korrekt. Das BuyFractal muss oberhalb des Alligators erscheinen, was nicht heißt, daß das nur der Fall ist, wenn sich die grüne Linie über den anderen befindet.
Weiterhin: Das Idealbuyfractal hat einen Bar, dessen Hoch höher ist als jeweils die beiden Hochs davor und dahinter. In der Fractalformel hier im Thread reicht ein anschließendes niedrigeres Hoch für ein Fractal, was aber nicht immer ein korrektes Ergebnis liefert.
@ gautama2
Es ist nicht richtig, wenn du schreibst, daß das BuyFractal oberhalb des Alligators liegen muß. Bill Williams drückt das so aus: "It is essential to understand that we would not take a fractal buy signal if, at the time it is hit, the price is below the Red Balance Line."
Das sagt nicht, daß grün über rot und rot über blau liegen muß, sondern lediglich, daß der Schittpunkt des Preises (Close) mit der BuyLine (Fractal High + 1 Tick als horizontale Linie) oberhalb der Red Balance Line liegen muß.
Ideal wäre es allerdings wenn die drei Linien eng beieinanderliegen, möglichst so eng, daß die Highs oberhalb und die Lows unterhalb der Balance Lines liegen, weil dann die Volatilität sehr niedrig ist und mit einer größeren Bewegung gerechnet werden kann.
Hallo,
Du hast recht, aber es steht gleich im übernächsten Satz: "Once a fractal signal is formed and is valid in relation to its position outside the alligators mouth, it reamins a signal until...."
Outside the alligators mouth verstehe ich als außerhalb aller 3 Linien und nicht nur der roten Linie. Vielleicht habe ich es auch falsch verstanden. Ich lese nochmal nach.
Inzwischen habe ich Antwort von profitunity:
THE AC is created from the last 5 bars on the AO. Take the last 5 entries
from the AO then subtract it from last entry. This is how to create the AC
histogram.
The average of the last 5 AO bars and then subtract that from the last
entry.
For ELA
Value1 = average (price, 5 )
Value 2 = average(price, 34 )
AO = Value1 - value 2;
Value4 = average (ao,5) ;
AC = AO - value 4;
If AC > AC (1) then plot 1 (AC,"AC Up")
If AC AC (1) then plot2 (AC, "AC down")
Plot 3 (0, "zero");
Die Formel von metatrader ist richtig außer daß es ein Simple MA sein müsste. Wie das mit dem Satz im Buch passen soll verstehe ich aber immer noch nicht. Aber es ist ja schon spät.
Viele Grüße
Ich habe nochmal gelesen.
Das Alligatormaul ist letztendlich nur die rote Linie und das BuyFractal muss auch nicht über der roten Linie auftauchen.
Aber der eigentliche Kauf aufgrund des Buyfractals muss über der roten Linie erfolgen. Bei Short umgekehrt. Dazu gibt es ein Beispiel im Buch, wann ein Signal Gültigkeit bekommt.
Mein Buysignal würde dann aber so aussehen:
Simple Up Fractal Buy, Pale green up
var1 := Fml("Alligator Green");
var2 := Fml("Alligator Red");
var3 := Fml("Alligator Blue");
Cross(H , Fml("Fractal Up") )
AND h>var2;
Viele Grüße
@ gautama2
Bill Williams schreibt irgendwo in seinem Buch das alle Signale als 'Stop Close Only' zu verstehen sind. Also müßte es heißen:
Cross(C,Fml("Fractal Up")) AND
C>var2
Soweit ich gelesen habe sind das nur die Stop Signale, nicht die Buy Signale.
Kannst Du die Seite im Buch nennen?
Mit 'Stop Close Only' meint Bill Williams nur die Stop Signale.
Gruss,
Martin