* Metastock: Intraday Pivot Points anzeigen lassen

Deine Frage ist im Grunde hier "gleich nebenan" schon beantwortet worden

http://www.terminmarktwelt.de/cgi-bin/tmw-forum.pl?ST=6409&CP=0

Gruß Rock

Hallo Rock,

den Beitrag habe ich auch gelesen, das hat mich aber auch nicht recht viel weitergebracht.

Kannst du mit vielleicht nur mal den Pivot Point selbst als Beispiel am Intraday Chart geben?

Danke!

Hallo,

ich bin nur MS EOD Anwender, aber aufbauend auf die Formel von gautama in dem gen. thread sollte es so gehen:

CoD := DayOfMonth() <> Ref(DayOfMonth(),-1);
HPd := If(Cod,H,If(H>PREV,H,PREV));
LPd := If(Cod,L,If(L<PREV,L,PREV));
LastHigh := If(CoD, Ref(HPd,-1),PREV);
LastLow := If(CoD, Ref(LPd,-1),PREV);
LastClose:= If(CoD, Ref(C,-1),PREV);
Pivot:=(LastHigh+LastLow+LastClose)/3;
R1:= 2*Pivot- LastLow;
Pivot;
R1;

und entsprechend noch für die anderen Pivot Levels.

Gruß Rock

Hi,

erstmal danke für deine Hilfe!

Doch genau sowas ähnliches habe ich auch schon ausprobiert. Das hat nicht funktioniert und diese Formel tut es leider auch nicht. Jetzt bekomme ich zwar zumindest einen Wert, aber der liegt 20% über dem momentanen Kurs. Ich habe es auch schon mit Market Start und Market End probiert, nichts hat funktioniert oder hat falsche Werte geliefert.

Ich weiss nun wirklich nicht mehr weiter. Ich werde wohl die Pivots wieder manuell einzeichnen.

Trotzdem Danke für die schnelle Hilfe.

Gruß

CME Trader

Seltsam, ich kann in der Formel keinen Fehler sehen, in meinem MS EOD funktioniert sie auch.

So wie ich sie eingestellt habe, als Indikator über den Dax gelegt, zeigt sie 2 Linien, die am 26.9. bei 3329,83 (Pivot) und 3358,27 (R1) stehen. Die Formel sollte nach meinem Verständnis intraday bei jeder eingestellten Periodizität richtig rechnen.

Vielleich kann noch jemand mit MS Pro Erfahrung helfen.

Gruß Rock

Hallo,

hier ist die korrekte Formel, Beispiel mit Bild im 5 Minuten Chart, Input ist 2:

TF:=Input("1=hour 2=day 3=week 4=month 5=year ",1,5,2);
NW:=If(TF=1,ROC(Minute(),1,$)<0,If(TF=2,ROC(Hour(),1,$)<0, If(TF=3,ROC(DayOfWeek(),1,$)<0,If(TF=4,ROC(DayOfMonth(),1,$)<0,ROC(Month(),1,$)<0))));

A1:=Cum(1);
A2:=LastValue(A1-BarsSince(NW>0));

HPd := If(nw,H,If(H>PREV,H,PREV));
LPd := If(nw,L,If(L<PREV,L,PREV));
LastHigh := If(nw, Ref(HPd,-1),PREV);
LastLow := If(nw, Ref(LPd,-1),PREV);
LastOpen:=If(nw,O,ValueWhen(2,nw,O));
LastClose := If(nw,C,ValueWhen(1,a1-a2=-1,C));

{P = Pivot Price}
Pivot:=(LastHigh + LastLow + LastClose)/3;
{R1 = 1st Resistance}
R1:=(2*(Pivot))-LastLow;
{S1 = 1st Support}
S1:=(2*(Pivot))-LastHigh;
{R2 = 2nd Resistance }
R2:=((Pivot)-(S1))+(R1);
{S2 = 2nd Support}
S2:=(Pivot)-((R1)-(S1));

If(A1<A2,BarsSince(A1>=A2),LastValue(Pivot));
If(A1<A2,BarsSince(A1>=A2),LastValue(R1));
If(A1<A2,BarsSince(A1>=A2),LastValue(S1));
If(A1<A2,BarsSince(A1>=A2),LastValue(R2));
If(A1<A2,BarsSince(A1>=A2),LastValue(S2))

@ metatrader

Vielen herzlichen Dank für deine Hilfe. Jetzt funktioniert es.

Hallo,

hier noch eine Version ohne PREV:

TF:=Input("1=hour 2=day 3=week 4=month 5=year ",1,5,2);
NW:=If(TF=1,ROC(Minute(),1,$)<0,If(TF=2,ROC(Hour(),1,$)<0, If(TF=3,ROC(DayOfWeek(),1,$)<0,If(TF=4,ROC(DayOfMonth(),1,$)<0,ROC(Month(),1,$)<0))));

A1:=Cum(1);
A2:=LastValue(A1-BarsSince(NW>0));

LastOpen:=If(nw,O,ValueWhen(2,nw,O));
LastHigh:=ValueWhen(1,Nw,Ref(HighestSince(1,Nw,H),-1));
LastLow:=ValueWhen(1,Nw,Ref(LowestSince(1,Nw,L),-1));
LastClose := If(nw,C,ValueWhen(1,a1-a2=-1,C));

{P = Pivot Price}
Pivot:=(LastHigh + LastLow + LastClose)/3;
{R1 = 1st Resistance}
R1:=(2*(Pivot))-LastLow;
{S1 = 1st Support}
S1:=(2*(Pivot))-LastHigh;
{R2 = 2nd Resistance }
R2:=((Pivot)-(S1))+(R1);
{S2 = 2nd Support}
S2:=(Pivot)-((R1)-(S1));

If(A1<A2,BarsSince(A1>=A2),LastValue(Pivot));
If(A1<A2,BarsSince(A1>=A2),LastValue(R1));
If(A1<A2,BarsSince(A1>=A2),LastValue(S1));
If(A1<A2,BarsSince(A1>=A2),LastValue(R2));
If(A1<A2,BarsSince(A1>=A2),LastValue(S2))

Hallo metatrader,

die Formel ist gut, aber ich schaffe es nicht sie für Overnight GAPs umzuarbeiten, weil man für die verschiedenen Zeiträume das Open braucht. Wie würde das hier gehen oder geht es vielleicht nicht?

Viele Grüße

Hallo,

ich verstehe die Frage nicht, wie soll denn das Overnight Gap in die Formel mit einfliessen?

Etwa in der Form, das rückwirkend H,L und/oder C an das Gap angepasst werden?